patch onetbb's assembler probe for native windows builds

oneTBB probes the GNU assembler version by compiling /dev/null, which does
not exist when a native Windows cmake drives mingw gcc. The compiler fails
with 'no input files', the version regex doesn't match, and math() then
chokes on the error text -- taking the whole configure down:

  CMake Error at cmake/compilers/GNU.cmake:65 (math):
    math cannot parse the expression: "g++.exe: error: /dev/null: No such
    file or directory ... * 1000 + ..."

MXE doesn't hit this because it cross-builds oneTBB from a POSIX host.

Use NUL on Windows, and treat an unparseable probe as an assembler too old
for waitpkg rather than a fatal error -- it only guards an optimization, and
Rtools42's GCC 10.4 is below the GCC 11 floor for -mwaitpkg regardless.

Author: kevinushey

patches/mingw_devnull.diff

@@ -0,0 +1,48 @@
+diff --git a/src/tbb/cmake/compilers/GNU.cmake b/src/tbb/cmake/compilers/GNU.cmake
+index cf6d8bdb..4c5e43a9 100644
+--- a/src/tbb/cmake/compilers/GNU.cmake
++++ b/src/tbb/cmake/compilers/GNU.cmake
+@@ -47,19 +47,42 @@ endif()
+ # >=2.31.1). Capturing the output in CMake can be done like below. The version
+ # information is written to either stdout or stderr. To not make any
+ # assumptions, both are captured.
++
++# The null device is spelled differently on Windows. A mingw build driven by
++# a native Windows CMake (rather than cross-compiled from a POSIX host) has no
++# '/dev/null', and the compiler would fail with "no input files".
++if (WIN32)
++    set(_tbb_null_device "NUL")
++else()
++    set(_tbb_null_device "/dev/null")
++endif()
++
+ execute_process(
+-    COMMAND ${CMAKE_COMMAND} -E env "LANG=C" ${CMAKE_CXX_COMPILER} -xc -c /dev/null -Wa,-v -o/dev/null
++    COMMAND ${CMAKE_COMMAND} -E env "LANG=C" ${CMAKE_CXX_COMPILER} -xc -c ${_tbb_null_device} -Wa,-v -o${_tbb_null_device}
+     OUTPUT_VARIABLE ASSEMBLER_VERSION_LINE_OUT
+     ERROR_VARIABLE ASSEMBLER_VERSION_LINE_ERR
+     OUTPUT_STRIP_TRAILING_WHITESPACE
+     ERROR_STRIP_TRAILING_WHITESPACE
+ )
++unset(_tbb_null_device)
+ set(ASSEMBLER_VERSION_LINE ${ASSEMBLER_VERSION_LINE_OUT}${ASSEMBLER_VERSION_LINE_ERR})
+ string(REGEX REPLACE ".*GNU assembler version ([0-9]+)\\.([0-9]+).*" "\\1" _tbb_gnu_asm_major_version "${ASSEMBLER_VERSION_LINE}")
+ string(REGEX REPLACE ".*GNU assembler version ([0-9]+)\\.([0-9]+).*" "\\2" _tbb_gnu_asm_minor_version "${ASSEMBLER_VERSION_LINE}")
+ unset(ASSEMBLER_VERSION_LINE_OUT)
+ unset(ASSEMBLER_VERSION_LINE_ERR)
+ unset(ASSEMBLER_VERSION_LINE)
++
++# When the version can't be parsed, the REGEX REPLACE calls above leave the
++# whole (unmatched) probe output behind, which math() below cannot evaluate.
++# Treat that as an assembler too old for waitpkg rather than failing the
++# configure outright -- the probe is only an optimization guard.
++if (NOT _tbb_gnu_asm_major_version MATCHES "^[0-9]+$" OR
++    NOT _tbb_gnu_asm_minor_version MATCHES "^[0-9]+$")
++    message(STATUS "Could not determine the GNU assembler version; assuming it predates waitpkg support")
++    set(_tbb_gnu_asm_major_version 0)
++    set(_tbb_gnu_asm_minor_version 0)
++endif()
++
+ message(TRACE "Extracted GNU assembler version: major=${_tbb_gnu_asm_major_version} minor=${_tbb_gnu_asm_minor_version}")
+ 
+ math(EXPR _tbb_gnu_asm_version_number  "${_tbb_gnu_asm_major_version} * 1000 + ${_tbb_gnu_asm_minor_version}")

src/tbb/cmake/compilers/GNU.cmake

@@ -47,19 +47,42 @@ endif()
 # >=2.31.1). Capturing the output in CMake can be done like below. The version
 # information is written to either stdout or stderr. To not make any
 # assumptions, both are captured.
+
+# The null device is spelled differently on Windows. A mingw build driven by
+# a native Windows CMake (rather than cross-compiled from a POSIX host) has no
+# '/dev/null', and the compiler would fail with "no input files".
+if (WIN32)
+    set(_tbb_null_device "NUL")
+else()
+    set(_tbb_null_device "/dev/null")
+endif()
+
 execute_process(
-    COMMAND ${CMAKE_COMMAND} -E env "LANG=C" ${CMAKE_CXX_COMPILER} -xc -c /dev/null -Wa,-v -o/dev/null
+    COMMAND ${CMAKE_COMMAND} -E env "LANG=C" ${CMAKE_CXX_COMPILER} -xc -c ${_tbb_null_device} -Wa,-v -o${_tbb_null_device}
     OUTPUT_VARIABLE ASSEMBLER_VERSION_LINE_OUT
     ERROR_VARIABLE ASSEMBLER_VERSION_LINE_ERR
     OUTPUT_STRIP_TRAILING_WHITESPACE
     ERROR_STRIP_TRAILING_WHITESPACE
 )
+unset(_tbb_null_device)
 set(ASSEMBLER_VERSION_LINE ${ASSEMBLER_VERSION_LINE_OUT}${ASSEMBLER_VERSION_LINE_ERR})
 string(REGEX REPLACE ".*GNU assembler version ([0-9]+)\\.([0-9]+).*" "\\1" _tbb_gnu_asm_major_version "${ASSEMBLER_VERSION_LINE}")
 string(REGEX REPLACE ".*GNU assembler version ([0-9]+)\\.([0-9]+).*" "\\2" _tbb_gnu_asm_minor_version "${ASSEMBLER_VERSION_LINE}")
 unset(ASSEMBLER_VERSION_LINE_OUT)
 unset(ASSEMBLER_VERSION_LINE_ERR)
 unset(ASSEMBLER_VERSION_LINE)
+
+# When the version can't be parsed, the REGEX REPLACE calls above leave the
+# whole (unmatched) probe output behind, which math() below cannot evaluate.
+# Treat that as an assembler too old for waitpkg rather than failing the
+# configure outright -- the probe is only an optimization guard.
+if (NOT _tbb_gnu_asm_major_version MATCHES "^[0-9]+$" OR
+    NOT _tbb_gnu_asm_minor_version MATCHES "^[0-9]+$")
+    message(STATUS "Could not determine the GNU assembler version; assuming it predates waitpkg support")
+    set(_tbb_gnu_asm_major_version 0)
+    set(_tbb_gnu_asm_minor_version 0)
+endif()
+
 message(TRACE "Extracted GNU assembler version: major=${_tbb_gnu_asm_major_version} minor=${_tbb_gnu_asm_minor_version}")
 
 math(EXPR _tbb_gnu_asm_version_number  "${_tbb_gnu_asm_major_version} * 1000 + ${_tbb_gnu_asm_minor_version}")